tools/cmake/Flags.cmake

   1 ##
   2 ## This file is in charge of setting our paranoid flags with regard to warnings and optimization.
   3 ##
   4 ##   It is only used for gcc and clang. MSVC builds don't load this file.
   5 ##
   6 ##   These flags do break some classical CMake tests, so you don't
   7 ##   want to do so before the very end of the configuration.
   8 ##
   9 ##   Other compiler flags (C/C++ standard version) are tested and set
  10 ##   by the beginning of the configuration, directly in ~/CMakeList.txt
  11
  12 set(warnCFLAGS "")
  13 set(optCFLAGS "")
  14 set(warnCXXFLAGS "")
  15
  16 if(enable_compile_warnings)
  17   set(warnCFLAGS "-fno-common -Wall -Wunused -Wmissing-declarations -Wpointer-arith -Wchar-subscripts -Wcomment -Wformat -Wwrite-strings -Wno-unused-function -Wno-unused-parameter -Wno-strict-aliasing")
  18   if(CMAKE_COMPILER_IS_GNUCC AND (NOT (CMAKE_C_COMPILER_VERSION VERSION_LESS "5.0")))
  19     set(warnCFLAGS "${warnCFLAGS} -Wformat-signedness")
  20   endif()
  21   if(CMAKE_COMPILER_IS_GNUCC)
  22     set(warnCFLAGS "${warnCFLAGS} -Wclobbered -Wno-error=clobbered  -Wno-unused-local-typedefs -Wno-error=attributes -Wno-error=maybe-uninitialized")
  23   endif()
  24   if (CMAKE_CXX_COMPILER_ID MATCHES "Intel")
  25     # ignore remark  #1418: external function definition with no prior declaration
  26     # 2196: routine is both "inline" and "noinline"
  27     # 3179: deprecated conversion of string literal to char* (should be const char*)
  28     # 191: type qualifier is meaningless on cast type
  29     # 597: entity-kind "entity" will not be called for implicit or explicit conversions
  30     # 2330: argument of type "type" is incompatible with parameter of type "type" (dropping qualifiers)
  31     set(warnCFLAGS "${warnCFLAGS} -wd1418 -wd191 -wd2196 -wd3179 -ww597 -ww2330")
  32   endif()
  33
  34   set(warnCXXFLAGS "${warnCFLAGS} -Wall -Wextra -Wunused -Wmissing-declarations -Wpointer-arith -Wchar-subscripts -Wcomment -Wformat -Wwrite-strings -Wno-unused-function -Wno-unused-parameter -Wno-strict-aliasing")
  35   if(CMAKE_COMPILER_IS_GNUCXX AND (NOT (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "5.0")))
  36     set(warnCFLAGS "${warnCFLAGS} -Wformat-signedness")
  37   endif()
  38   if(CMAKE_COMPILER_IS_GNUCXX)
  39     set(warnCXXFLAGS "${warnCXXFLAGS} -Wclobbered -Wno-error=clobbered  -Wno-unused-local-typedefs -Wno-error=attributes -Wno-error=maybe-uninitialized")
  40   endif()
  41   if (CMAKE_CXX_COMPILER_ID MATCHES "Clang")
  42     # don't care about class that become struct, avoid issue of empty C structs
  43     # size (coming from libunwind.h)
  44     set(warnCXXFLAGS "${warnCXXFLAGS} -Wno-mismatched-tags -Wno-extern-c-compat")
  45   endif()
  46
  47   # the one specific to C but refused by C++
  48   set(warnCFLAGS "${warnCFLAGS} -Wmissing-prototypes")
  49
  50   if(CMAKE_Fortran_COMPILER_ID MATCHES "GCC|PGI")
  51     set(CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} -Wall")
  52   elseif(CMAKE_Fortran_COMPILER_ID MATCHES "Flang")
  53     # flang >= 7 has a bug with common and debug flags. Ignore cmake-added -g in this case.
  54     # https://github.com/flang-compiler/flang/issues/671
  55     set(CMAKE_Fortran_FLAGS "-Wall")
  56   elseif(CMAKE_Fortran_COMPILER_ID MATCHES "Intel")
  57     set(CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} -warn all")
  58   endif()
  59   set(CMAKE_JAVA_COMPILE_FLAGS "-Xlint")
  60 endif()
  61
  62 # NDEBUG gives a lot of "initialized but unused variables" errors. Don't die anyway.
  63 if(enable_compile_warnings AND enable_debug)
  64   set(warnCFLAGS "${warnCFLAGS} -Werror")
  65   set(warnCXXFLAGS "${warnCXXFLAGS} -Werror")
  66   if(CMAKE_Fortran_COMPILER_ID MATCHES "GCC")
  67     set(CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} -Werror -Werror=format-security")
  68   endif()
  69 endif()
  70
  71 # Activate the warnings on #if FOOBAR when FOOBAR has no value
  72 # It breaks on FreeBSD within Boost headers, so activate this only in Pure Hardcore debug mode.
  73 if(enable_maintainer_mode)
  74   set(warnCFLAGS "${warnCFLAGS} -Wundef")
  75   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wundef")
  76 endif()
  77
  78 # Se the optimisation flags
  79 # NOTE, we should CMAKE_BUILD_TYPE for this
  80 if(enable_compile_optimizations)
  81   set(optCFLAGS "-O3 -funroll-loops -fno-strict-aliasing ")
  82 else()
  83   set(optCFLAGS "-O0 ")
  84 endif()
  85 if(enable_compile_optimizations AND CMAKE_COMPILER_IS_GNUCC
  86     AND (NOT enable_model-checking))
  87   # This is redundant (already in -03):
  88   set(optCFLAGS "${optCFLAGS} -finline-functions ")
  89 endif()
  90
  91 # Do not leak the current directory into the binaries
  92 if(CMAKE_COMPILER_IS_GNUCC)
  93   execute_process(COMMAND realpath --relative-to=${CMAKE_BINARY_DIR} ${CMAKE_SOURCE_DIR}
  94     RESULT_VARIABLE RESULT OUTPUT_VARIABLE RELATIVE_SOURCE_DIR ERROR_QUIET OUTPUT_STRIP_TRAILING_WHITESPACE)
  95   if(RESULT EQUAL 0)
  96     message(STATUS "Relative source directory is \"${RELATIVE_SOURCE_DIR}\".")
  97   else()
  98     message(WARNING "Failed to find relative source directory. Using \".\".")
  99     set(RELATIVE_SOURCE_DIR ".")
 100   endif()
 101   if (CMAKE_C_COMPILER_VERSION VERSION_LESS "8.0")
 102     set(optCFLAGS "${optCFLAGS} -fdebug-prefix-map=${CMAKE_SOURCE_DIR}=${RELATIVE_SOURCE_DIR}")
 103   else()
 104     set(optCFLAGS "${optCFLAGS} -ffile-prefix-map=${CMAKE_SOURCE_DIR}=${RELATIVE_SOURCE_DIR}")
 105   endif()
 106 endif()
 107
 108 # Configure LTO
 109 # NOTE, cmake 3.0 has a INTERPROCEDURAL_OPTIMIZATION target
 110 #       property for this (http://www.cmake.org/cmake/help/v3.0/prop_tgt/INTERPROCEDURAL_OPTIMIZATION.html)
 111 if(enable_lto) # User wants LTO. Try if we can do that
 112   set(enable_lto OFF)
 113   if(enable_compile_optimizations
 114       AND CMAKE_COMPILER_IS_GNUCC
 115       AND (NOT enable_model-checking))
 116     # On windows, we need 4.8 or higher to enable lto because of http://gcc.gnu.org/bugzilla/show_bug.cgi?id=50293
 117     #   We are experiencing assertion failures even with 4.8 on MinGW.
 118     #   Push the support forward: will see if 4.9 works when we test it.
 119     #
 120     # On Linux, we got the following with GCC 4.8.4 on Centos and Ubuntu
 121     #    lto1: internal compiler error: in output_die, at dwarf2out.c:8478
 122     #    Please submit a full bug report, with preprocessed source if appropriate.
 123     # So instead, we push the support forward
 124
 125     if ( (CMAKE_C_COMPILER_VERSION VERSION_GREATER "4.8.5")
 126          AND (LINKER_VERSION VERSION_GREATER "2.22"))
 127       set(enable_lto ON)
 128     endif()
 129   endif()
 130   if(enable_lto)
 131     message(STATUS "LTO seems usable.")
 132   else()
 133     if(NOT enable_compile_optimizations)
 134       message(STATUS "LTO disabled: Compile-time optimizations turned off.")
 135     else()
 136       if(enable_model-checking)
 137         message(STATUS "LTO disabled when compiling with model-checking.")
 138       else()
 139         message(STATUS "LTO does not seem usable -- try updating your build chain.")
 140       endif()
 141     endif()
 142   endif()
 143 else()
 144   message(STATUS "LTO disabled on the command line.")
 145 endif()
 146 if(enable_lto) # User wants LTO, and it seems usable. Go for it
 147   set(optCFLAGS "${optCFLAGS} -flto ")
 148   # See https://gcc.gnu.org/wiki/LinkTimeOptimizationFAQ#ar.2C_nm_and_ranlib:
 149   # "Since version 4.9 gcc produces slim object files that only contain
 150   # the intermediate representation. In order to handle archives of
 151   # these objects you have to use the gcc wrappers:
 152   # gcc-ar, gcc-nm and gcc-ranlib."
 153   if(${CMAKE_C_COMPILER_ID} STREQUAL "GNU"
 154       AND CMAKE_C_COMPILER_VERSION VERSION_GREATER "4.8")
 155     set (CMAKE_AR gcc-ar)
 156     set (CMAKE_RANLIB gcc-ranlib)
 157   endif()
 158 endif()
 159
 160 if(enable_model-checking AND enable_compile_optimizations)
 161   # Forget it, do not optimize the code (because it confuses the MC):
 162   set(optCFLAGS "-O0 ")
 163   # But you can still optimize this:
 164   foreach(s
 165       src/simix/popping.cpp src/simix/popping_generated.cpp src/simix/smx_global.cpp
 166       ${SURF_SRC} ${TRACING_SRC} ${XBT_SRC}
 167       ${MC_SRC_BASE} ${MC_SRC})
 168       set (mcCFLAGS "-O3  -funroll-loops -fno-strict-aliasing")
 169        if(CMAKE_COMPILER_IS_GNUCC)
 170          set (mcCFLAGS "${mcCFLAGS} -finline-functions")
 171       endif()
 172       set_source_files_properties(${s} PROPERTIES COMPILE_FLAGS ${mcCFLAGS})
 173   endforeach()
 174 endif()
 175
 176 if (CMAKE_C_COMPILER_ID MATCHES "Intel")
 177   # honor parentheses when determining the order of expression evaluation.
 178   set(optCFLAGS "${optCFLAGS} -fprotect-parens ")
 179 endif()
 180
 181 if(NOT enable_debug)
 182   set(CMAKE_C_FLAGS "-DNDEBUG ${CMAKE_C_FLAGS}")
 183   set(CMAKE_CXX_FLAGS "-DNDEBUG ${CMAKE_CXX_FLAGS}")
 184 endif()
 185
 186 set(CMAKE_C_FLAGS   "${warnCFLAGS} ${CMAKE_C_FLAGS}   ${optCFLAGS}")
 187 set(CMAKE_CXX_FLAGS "${warnCXXFLAGS} ${CMAKE_CXX_FLAGS} ${optCFLAGS}")
 188
 189 # Try to make Mac a bit more complient to open source standards
 190 if(CMAKE_SYSTEM_NAME MATCHES "Darwin")
 191   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_XOPEN_SOURCE=700 -D_DARWIN_C_SOURCE")
 192 endif()
 193
 194 # Avoid a failure seen with gcc 7.2.0 and ns3 3.27
 195 if(enable_ns3)
 196   set_source_files_properties(src/surf/network_ns3.cpp PROPERTIES COMPILE_FLAGS " -Wno-unused-local-typedef")
 197 endif()
 198
 199 set(TESH_OPTION "")
 200 if(enable_coverage)
 201   find_program(GCOV_PATH gcov)
 202   if(GCOV_PATH)
 203     set(COVERAGE_COMMAND "${GCOV_PATH}" CACHE TYPE FILEPATH FORCE)
 204     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -DCOVERAGE")
 205     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fprofile-arcs -ftest-coverage")
 206     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -fprofile-arcs -ftest-coverage")
 207     set(CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} -fprofile-arcs -ftest-coverage")
 208     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -DCOVERAGE")
 209     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fprofile-arcs -ftest-coverage")
 210     add_definitions(-fprofile-arcs -ftest-coverage)
 211   endif()
 212 endif()
 213
 214 if(enable_address_sanitizer)
 215     set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS} -fsanitize=address -fno-omit-frame-pointer")
 216     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fsanitize=address -fno-omit-frame-pointer")
 217     set(CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} -fsanitize=address")
 218     set(TESH_OPTION --enable-sanitizers)
 219     try_compile(HAVE_SANITIZER_ADDRESS ${CMAKE_BINARY_DIR} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_asan.cpp)
 220     try_compile(HAVE_SANITIZER_ADDRESS_FIBER_SUPPORT ${CMAKE_BINARY_DIR} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_asan.cpp
 221       COMPILE_DEFINITIONS -DCHECK_FIBER_SUPPORT)
 222 else()
 223     set(HAVE_SANITIZER_ADDRESS FALSE CACHE INTERNAL "")
 224     set(HAVE_SANITIZER_ADDRESS_FIBER_SUPPORT FALSE CACHE INTERNAL "")
 225 endif()
 226
 227 if(enable_thread_sanitizer)
 228     set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS} -fsanitize=thread -fno-omit-frame-pointer -no-pie")
 229     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fsanitize=thread -fno-omit-frame-pointer -no-pie")
 230     set(CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} -fsanitize=thread -no-pie")
 231     try_compile(HAVE_SANITIZER_THREAD ${CMAKE_BINARY_DIR} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_tsan.cpp)
 232     try_compile(HAVE_SANITIZER_THREAD_FIBER_SUPPORT ${CMAKE_BINARY_DIR} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_tsan.cpp
 233       COMPILE_DEFINITIONS -DCHECK_FIBER_SUPPORT)
 234 else()
 235     set(HAVE_SANITIZER_THREAD FALSE CACHE INTERNAL "")
 236     set(HAVE_SANITIZER_THREAD_FIBER_SUPPORT FALSE CACHE INTERNAL "")
 237 endif()
 238
 239 if(enable_undefined_sanitizer)
 240     set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS} -fsanitize=undefined -fno-omit-frame-pointer")
 241     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fsanitize=undefined -fno-omit-frame-pointer")
 242     set(CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} -fsanitize=undefined")
 243 endif()
 244
 245 if(NOT $ENV{CFLAGS} STREQUAL "")
 246   message(STATUS "Add CFLAGS: \"$ENV{CFLAGS}\" to CMAKE_C_FLAGS")
 247   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} $ENV{CFLAGS}")
 248 endif()
 249
 250 if(NOT $ENV{CXXFLAGS} STREQUAL "")
 251   message(STATUS "Add CXXFLAGS: \"$ENV{CXXFLAGS}\" to CMAKE_CXX_FLAGS")
 252   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} $ENV{CXXFLAGS}")
 253 endif()
 254
 255 if(NOT $ENV{LDFLAGS} STREQUAL "")
 256   message(STATUS "Add LDFLAGS: \"$ENV{LDFLAGS}\" to CMAKE_C_LINK_FLAGS")
 257   set(CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} $ENV{LDFLAGS}")
 258 endif()
 259
 260 if(MINGW)
 261   # http://stackoverflow.com/questions/10452262/create-64-bit-jni-under-windows
 262   # We don't want to ship libgcc_s_seh-1.dll nor libstdc++-6.dll
 263   set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS}   -static-libgcc")
 264   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -static-libgcc -static-libstdc++")
 265   set(CMAKE_SHARED_LIBRARY_LINK_C_FLAGS   "${CMAKE_SHARED_LIBRARY_LINK_C_FLAGS} -static-libgcc")
 266   set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "${CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS} -static-libgcc -static-libstdc++")
 267
 268   # JNI searches for stdcalls
 269   set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS}   -Wl,--add-stdcall-alias")
 270   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wl,--add-stdcall-alias")
 271   set(CMAKE_SHARED_LIBRARY_LINK_C_FLAGS "${CMAKE_SHARED_LIBRARY_LINK_C_FLAGS} -Wl,--add-stdcall-alias")
 272   set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "${CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS} -Wl,--add-stdcall-alias")
 273
 274   # Specify the data model that we are using (yeah it may help Java)
 275   if(CMAKE_SIZEOF_VOID_P EQUAL 4) # 32 bits
 276     set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS}   -m32")
 277     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -m32")
 278   else()
 279     set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS}   -m64")
 280     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -m64")
 281   endif()
 282 endif()