tools/cmake/Flags.cmake

   1 ##
   2 ## This file is in charge of setting our paranoid flags with regard to warnings and optimization.
   3 ##
   4 ##   It is only used for gcc, clang and Intel compilers.
   5 ##
   6 ##   These flags do break some classical CMake tests, so you don't
   7 ##   want to do so before the very end of the configuration.
   8 ##
   9 ##   Other compiler flags (C/C++ standard version) are tested and set
  10 ##   by the beginning of the configuration, directly in ~/CMakeList.txt
  11
  12 set(warnCFLAGS "")
  13 set(optCFLAGS "")
  14 set(warnCXXFLAGS "")
  15
  16 if(enable_compile_warnings)
  17   set(warnCFLAGS "-fno-common -Wall -Wextra -Wunused -Wmissing-declarations -Wpointer-arith -Wwrite-strings -Wno-unused-function -Wno-unused-local-typedefs -Wno-unused-parameter -Wno-strict-aliasing")
  18
  19   if (CMAKE_CXX_COMPILER_ID MATCHES "Intel")
  20     # ignore remarks:
  21     # 191: type qualifier is meaningless on cast type
  22     # 1418: external function definition with no prior declaration
  23     # 2196: routine is both "inline" and "noinline"
  24     # 2651: attribute does not apply to any entity
  25     # 3179: deprecated conversion of string literal to char* (should be const char*)
  26     # set as warning:
  27     # 597: entity-kind "entity" will not be called for implicit or explicit conversions
  28     # 2330: argument of type "type" is incompatible with parameter of type "type" (dropping qualifiers)
  29     # 11003: no IR in object file xxxx; was the source file compiled with xxxx
  30     set(warnCFLAGS "${warnCFLAGS} -diag-disable=191,1418,2196,2651,3179 -diag-warning=597,2330,11003")
  31   endif()
  32   set(warnCXXFLAGS "${warnCFLAGS}")
  33
  34   if(CMAKE_COMPILER_IS_GNUCC)
  35     set(warnCFLAGS "${warnCFLAGS} -Wclobbered -Wformat-signedness -Wno-error=clobbered -Wno-error=attributes -Wno-error=maybe-uninitialized")
  36   endif()
  37
  38   if(CMAKE_COMPILER_IS_GNUCXX)
  39     set(warnCXXFLAGS "${warnCXXFLAGS} -Wclobbered -Wformat-signedness -Wno-error=clobbered -Wno-free-nonheap-object -Wno-unused-local-typedefs -Wno-error=attributes -Wno-error=maybe-uninitialized")
  40     if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS "8.0")
  41       # workaround for https://gcc.gnu.org/bugzilla/show_bug.cgi?id=81767
  42       set(warnCXXFLAGS "${warnCXXFLAGS} -Wno-error=unused-variable")
  43     endif()
  44   endif()
  45
  46   if (CMAKE_CXX_COMPILER_ID MATCHES "Clang")
  47     # don't care about class that become struct, avoid issue of empty C structs
  48     # size (coming from libunwind.h)
  49     set(warnCXXFLAGS "${warnCXXFLAGS} -Wno-mismatched-tags -Wno-extern-c-compat")
  50     # also ignore deprecated builtins (seen with clang 15 + boost 1.79)
  51     if(CMAKE_CXX_COMPILER_VERSION VERSION_GREATER_EQUAL "15.0")
  52       set(warnCXXFLAGS "${warnCXXFLAGS} -Wno-deprecated-builtins")
  53     endif()
  54   endif()
  55
  56   # the one specific to C but refused by C++
  57   set(warnCFLAGS "${warnCFLAGS} -Wmissing-prototypes")
  58
  59   if(CMAKE_Fortran_COMPILER_ID MATCHES "GCC|PGI")
  60     set(CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} -Wall")
  61   elseif(CMAKE_Fortran_COMPILER_ID MATCHES "Flang")
  62     # flang >= 7 has a bug with common and debug flags. Ignore cmake-added -g in this case.
  63     # https://github.com/flang-compiler/flang/issues/671
  64     set(CMAKE_Fortran_FLAGS "-Wall")
  65   elseif(CMAKE_Fortran_COMPILER_ID MATCHES "Intel")
  66     set(CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} -warn all")
  67   endif()
  68 endif()
  69
  70 # NDEBUG gives a lot of "initialized but unused variables" errors. Don't die anyway.
  71 if(enable_compile_warnings AND enable_debug)
  72   set(warnCFLAGS "${warnCFLAGS} -Werror")
  73   set(warnCXXFLAGS "${warnCXXFLAGS} -Werror")
  74   if(CMAKE_Fortran_COMPILER_ID MATCHES "GCC")
  75     set(CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} -Werror -Werror=format-security")
  76   endif()
  77 endif()
  78
  79 # Activate the warnings on #if FOOBAR when FOOBAR has no value
  80 # It used to break on FreeBSD within Boost headers and was only activated in maintainer mode, but I hope it works nowadays
  81 set(warnCFLAGS "${warnCFLAGS} -Wundef")
  82 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wundef")
  83
  84 # Set the optimisation flags
  85 # NOTE, we should CMAKE_BUILD_TYPE for this
  86 if(enable_compile_optimizations)
  87   set(optCFLAGS "-O3 -funroll-loops -fno-strict-aliasing ")
  88 else()
  89   set(optCFLAGS "-O0 ")
  90 endif()
  91
  92 # ARM platforms have signed char by default, switch to unsigned for consistancy
  93 if(${CMAKE_SYSTEM_PROCESSOR} MATCHES "aarch64")
  94   set(optCFLAGS "${optCFLAGS} -fsigned-char")
  95 endif()
  96
  97 if(enable_compile_optimizations AND CMAKE_COMPILER_IS_GNUCC)
  98   # This is redundant (already in -03):
  99   set(optCFLAGS "${optCFLAGS} -finline-functions ")
 100 endif()
 101
 102 # Do not leak the current directory into the binaries
 103 if(CMAKE_COMPILER_IS_GNUCC AND NOT enable_coverage)
 104   if (CMAKE_VERSION VERSION_LESS "3.20")
 105     file(RELATIVE_PATH RELATIVE_SOURCE_DIR ${CMAKE_BINARY_DIR} ${CMAKE_SOURCE_DIR})
 106   else() # cmake >= 3.20
 107     cmake_path(RELATIVE_PATH CMAKE_SOURCE_DIR BASE_DIRECTORY ${CMAKE_BINARY_DIR} OUTPUT_VARIABLE RELATIVE_SOURCE_DIR)
 108   endif()
 109   message(STATUS "Relative source directory is \"${RELATIVE_SOURCE_DIR}\".")
 110   if (CMAKE_C_COMPILER_VERSION VERSION_LESS "8.0")
 111     set(optCFLAGS "${optCFLAGS} -fdebug-prefix-map=\"${CMAKE_SOURCE_DIR}=${RELATIVE_SOURCE_DIR}\"")
 112   else()
 113     set(optCFLAGS "${optCFLAGS} -ffile-prefix-map=\"${CMAKE_SOURCE_DIR}=${RELATIVE_SOURCE_DIR}\"")
 114   endif()
 115 endif()
 116
 117 # Configure LTO
 118 if(enable_lto) # User wants LTO. Try if we can do that
 119   set(enable_lto OFF)
 120   if(enable_compile_optimizations)
 121     include(CheckIPOSupported)
 122     check_ipo_supported(RESULT ipo LANGUAGES C CXX)
 123     if(ipo)
 124       set(enable_lto ON)
 125     endif()
 126   endif()
 127
 128   if(enable_lto)
 129     message(STATUS "LTO seems usable.")
 130   else()
 131     if(NOT enable_compile_optimizations)
 132       message(STATUS "LTO disabled: Compile-time optimizations turned off.")
 133     else()
 134       message(STATUS "LTO does not seem usable -- try updating your build chain.")
 135     endif()
 136   endif()
 137 else()
 138   message(STATUS "LTO disabled on the command line.")
 139 endif()
 140 if(enable_lto) # User wants LTO, and it seems usable. Go for it
 141   set(CMAKE_INTERPROCEDURAL_OPTIMIZATION TRUE)
 142   if(LTO_EXTRA_FLAG AND CMAKE_COMPILER_IS_GNUCC)
 143     list(APPEND CMAKE_C_COMPILE_OPTIONS_IPO "-flto=${LTO_EXTRA_FLAG}")
 144     list(APPEND CMAKE_CXX_COMPILE_OPTIONS_IPO "-flto=${LTO_EXTRA_FLAG}")
 145   endif()
 146
 147   # Activate fat-lto-objects in case LD and gfortran differ too much.
 148   # Only test with GNU as it's the only case I know (clang+gfortran+lld)
 149   execute_process(COMMAND ${CMAKE_LINKER} -v OUTPUT_VARIABLE LINKER_ID ERROR_VARIABLE LINKER_ID)
 150   string(REGEX MATCH "GNU" LINKER_ID "${LINKER_ID}")
 151   if(${CMAKE_Fortran_COMPILER_ID} MATCHES "GNU"
 152      AND NOT "${LINKER_ID}" MATCHES "GNU")
 153        list(APPEND CMAKE_Fortran_COMPILE_OPTIONS_IPO "-ffat-lto-objects")
 154   endif()
 155
 156   # "Since version 4.9 gcc produces slim object files that only contain
 157   # the intermediate representation. In order to handle archives of
 158   # these objects you have to use the gcc wrappers:
 159   # gcc-ar, gcc-nm and gcc-ranlib."
 160   if(${CMAKE_C_COMPILER_ID} STREQUAL "GNU"
 161       AND CMAKE_C_COMPILER_VERSION VERSION_GREATER "4.8")
 162     set (CMAKE_AR gcc-ar)
 163     set (CMAKE_RANLIB gcc-ranlib)
 164   endif()
 165 endif()
 166
 167 if (CMAKE_C_COMPILER_ID MATCHES "Intel")
 168   # honor parentheses when determining the order of expression evaluation.
 169   # disallow optimizations for floating-point arithmetic with Nans or +-Infs (breaks Eigen3)
 170   set(optCFLAGS "${optCFLAGS} -fprotect-parens -fno-finite-math-only")
 171 endif()
 172
 173 if(NOT enable_debug)
 174   set(CMAKE_C_FLAGS "-DNDEBUG ${CMAKE_C_FLAGS}")
 175   set(CMAKE_CXX_FLAGS "-DNDEBUG ${CMAKE_CXX_FLAGS}")
 176 endif()
 177
 178 set(CMAKE_C_FLAGS   "${warnCFLAGS} ${CMAKE_C_FLAGS}   ${optCFLAGS}")
 179 set(CMAKE_CXX_FLAGS "${warnCXXFLAGS} ${CMAKE_CXX_FLAGS} ${optCFLAGS}")
 180
 181 # Try to make Mac a bit more compliant to open source standards
 182 if(CMAKE_SYSTEM_NAME MATCHES "Darwin")
 183   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_XOPEN_SOURCE=700 -D_DARWIN_C_SOURCE")
 184 endif()
 185
 186 set(TESH_OPTION "")
 187 if(enable_coverage)
 188   find_program(GCOV_PATH NAMES ENV{GCOV} gcov)
 189   if(GCOV_PATH)
 190     set(COVERAGE_COMMAND "${GCOV_PATH}" CACHE FILEPATH "Coverage testing tool (gcov)" FORCE)
 191     set(COVERAGE_BUILD_FLAGS "-fprofile-arcs -ftest-coverage -fprofile-abs-path")
 192     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -DCOVERAGE ${COVERAGE_BUILD_FLAGS}")
 193     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${COVERAGE_BUILD_FLAGS}")
 194     set(CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} ${COVERAGE_BUILD_FLAGS}")
 195     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -DCOVERAGE ${COVERAGE_BUILD_FLAGS}")
 196     add_definitions(${COVERAGE_BUILD_FLAGS})
 197   endif()
 198 endif()
 199
 200 if(enable_address_sanitizer)
 201     set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS} -fsanitize=address -fno-omit-frame-pointer")
 202     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fsanitize=address -fno-omit-frame-pointer")
 203     set(CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} -fsanitize=address")
 204     set(TESH_OPTION --enable-sanitizers)
 205     try_compile(HAVE_SANITIZER_ADDRESS ${CMAKE_BINARY_DIR} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_asan.cpp)
 206     try_compile(HAVE_SANITIZER_ADDRESS_FIBER_SUPPORT ${CMAKE_BINARY_DIR} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_asan.cpp
 207       COMPILE_DEFINITIONS -DCHECK_FIBER_SUPPORT)
 208 else()
 209     set(HAVE_SANITIZER_ADDRESS FALSE CACHE INTERNAL "")
 210     set(HAVE_SANITIZER_ADDRESS_FIBER_SUPPORT FALSE CACHE INTERNAL "")
 211 endif()
 212
 213 if(enable_thread_sanitizer)
 214     set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS} -fsanitize=thread -fno-omit-frame-pointer -no-pie")
 215     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fsanitize=thread -fno-omit-frame-pointer -no-pie")
 216     if(CMAKE_COMPILER_IS_GNUCXX AND (NOT (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "12.0")))
 217         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-error=tsan")
 218     endif()
 219     set(CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} -fsanitize=thread -no-pie")
 220     try_compile(HAVE_SANITIZER_THREAD ${CMAKE_BINARY_DIR} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_tsan.cpp)
 221     try_compile(HAVE_SANITIZER_THREAD_FIBER_SUPPORT ${CMAKE_BINARY_DIR} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_tsan.cpp
 222       COMPILE_DEFINITIONS -DCHECK_FIBER_SUPPORT)
 223 else()
 224     set(HAVE_SANITIZER_THREAD FALSE CACHE INTERNAL "")
 225     set(HAVE_SANITIZER_THREAD_FIBER_SUPPORT FALSE CACHE INTERNAL "")
 226 endif()
 227
 228 if(enable_undefined_sanitizer)
 229     set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS} -fsanitize=undefined -fno-omit-frame-pointer")
 230     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fsanitize=undefined -fno-omit-frame-pointer")
 231     set(CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} -fsanitize=undefined")
 232 endif()
 233
 234 if(NOT $ENV{CFLAGS} STREQUAL "")
 235   message(STATUS "Add CFLAGS: \"$ENV{CFLAGS}\" to CMAKE_C_FLAGS")
 236   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} $ENV{CFLAGS}")
 237 endif()
 238
 239 if(NOT $ENV{CXXFLAGS} STREQUAL "")
 240   message(STATUS "Add CXXFLAGS: \"$ENV{CXXFLAGS}\" to CMAKE_CXX_FLAGS")
 241   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} $ENV{CXXFLAGS}")
 242 endif()
 243
 244 if(NOT $ENV{LDFLAGS} STREQUAL "")
 245   message(STATUS "Add LDFLAGS: \"$ENV{LDFLAGS}\" to CMAKE_C_LINK_FLAGS")
 246   set(CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} $ENV{LDFLAGS}")
 247 endif()