buildtools/Cmake/MakeLib.cmake

   1 ### Make Libs
   2
   3
   4 # Try to make Mac a bit more complient to open source standards
   5 if(CMAKE_SYSTEM_NAME MATCHES "Darwin")
   6         add_definitions("-D_XOPEN_SOURCE")
   7 endif(CMAKE_SYSTEM_NAME MATCHES "Darwin")
   8
   9 ###############################
  10 # Declare the library content #
  11 ###############################
  12 # If we want supernovae, rewrite the libs' content to use it
  13 include(${CMAKE_HOME_DIRECTORY}/buildtools/Cmake/Supernovae.cmake)
  14
  15 # Actually declare our libraries
  16
  17 add_library(simgrid SHARED ${simgrid_sources})
  18 set_target_properties(simgrid PROPERTIES VERSION ${libsimgrid_version})
  19
  20 add_library(gras SHARED ${gras_sources})
  21 set_target_properties(gras PROPERTIES VERSION ${libgras_version})
  22
  23 if(enable_lib_static)
  24         add_library(simgrid_static STATIC ${simgrid_sources})
  25 endif(enable_lib_static)
  26
  27 if(enable_smpi)
  28         add_library(smpi SHARED ${SMPI_SRC})
  29         set_target_properties(smpi PROPERTIES VERSION ${libsmpi_version})
  30         if(enable_lib_static)
  31                 add_library(smpi_static STATIC ${SMPI_SRC})
  32         endif(enable_lib_static)
  33 endif(enable_smpi)
  34
  35 add_dependencies(gras maintainer_files)
  36 add_dependencies(simgrid maintainer_files)
  37
  38 # if supernovaeing, we need some depends to make sure that the source gets generated
  39 if (enable_supernovae)
  40         add_dependencies(simgrid ${CMAKE_CURRENT_BINARY_DIR}/src/supernovae_sg.c)
  41         if(enable_lib_static)
  42                 add_dependencies(simgrid_static ${CMAKE_CURRENT_BINARY_DIR}/src/supernovae_sg.c)
  43         endif(enable_lib_static)
  44         add_dependencies(gras ${CMAKE_CURRENT_BINARY_DIR}/src/supernovae_gras.c)
  45
  46         if(enable_smpi)
  47                 add_dependencies(smpi ${CMAKE_CURRENT_BINARY_DIR}/src/supernovae_smpi.c)
  48                 if(enable_lib_static)
  49                         add_dependencies(smpi_static ${CMAKE_CURRENT_BINARY_DIR}/src/supernovae_smpi.c)
  50                 endif(enable_lib_static)
  51         endif(enable_smpi)
  52 endif(enable_supernovae)
  53
  54 # Compute the dependencies of GRAS
  55 ##################################
  56 set(GRAS_DEP "-lm -lpthread")
  57
  58 if(HAVE_POSIX_GETTIME)
  59         SET(GRAS_DEP "${GRAS_DEP} -lrt")
  60 endif(HAVE_POSIX_GETTIME)
  61
  62 # the following is probably unneed since it kills the previous
  63 # GRAS_DEP (and is thus probably invalid).
  64 # My guess is that pthread is never true [Mt]
  65 # FIXME: KILLME if we get a working windows with that?
  66 if(with_context MATCHES windows)
  67 if(pthread)
  68                 SET(GRAS_DEP "msg")
  69 endif(pthread)
  70 endif(with_context MATCHES windows)
  71 target_link_libraries(gras      ${GRAS_DEP})
  72
  73 # Compute the dependencies of SimGrid
  74 #####################################
  75 set(SIMGRID_DEP "-lm")
  76 if(HAVE_PCRE_LIB)
  77        SET(SIMGRID_DEP "${SIMGRID_DEP} -lpcre")
  78 endif(HAVE_PCRE_LIB)
  79
  80 if(pthread)
  81         if(${CONTEXT_THREADS})
  82                 SET(SIMGRID_DEP "${SIMGRID_DEP} -lpthread")
  83         endif(${CONTEXT_THREADS})
  84 endif(pthread)
  85
  86 if(HAVE_GRAPHVIZ)
  87     if(HAVE_CGRAPH_LIB)
  88             SET(SIMGRID_DEP "${SIMGRID_DEP} -lcgraph")
  89         else(HAVE_CGRAPH_LIB)
  90         if(HAVE_AGRAPH_LIB)
  91             SET(SIMGRID_DEP "${SIMGRID_DEP} -lagraph -lcdt")
  92         endif(HAVE_AGRAPH_LIB)
  93     endif(HAVE_CGRAPH_LIB)
  94 endif(HAVE_GRAPHVIZ)
  95
  96 if(HAVE_GTNETS)
  97         SET(SIMGRID_DEP "${SIMGRID_DEP} -lgtnets")
  98 endif(HAVE_GTNETS)
  99
 100 if(HAVE_POSIX_GETTIME)
 101         SET(SIMGRID_DEP "${SIMGRID_DEP} -lrt")
 102 endif(HAVE_POSIX_GETTIME)
 103
 104 target_link_libraries(simgrid   ${SIMGRID_DEP})
 105
 106 # Compute the dependencies of SMPI
 107 ##################################
 108 set(SMPI_LDEP "")
 109 if(APPLE)
 110     set(SMPI_LDEP "-Wl,-U -Wl,_smpi_simulated_main")
 111 endif(APPLE)
 112 if(enable_smpi)
 113         target_link_libraries(smpi      simgrid ${SMPI_LDEP})
 114 endif(enable_smpi)
 115
 116 # Pass dependencies to static libs
 117 ##################################
 118 if(enable_lib_static)
 119         target_link_libraries(simgrid_static    ${SIMGRID_DEP})
 120         add_dependencies(simgrid_static maintainer_files)
 121         set_target_properties(simgrid_static PROPERTIES OUTPUT_NAME simgrid)
 122         if(enable_smpi)
 123                 target_link_libraries(smpi_static       simgrid ${SMPI_LDEP})
 124                 set_target_properties(smpi_static PROPERTIES OUTPUT_NAME smpi)
 125         endif(enable_smpi)
 126 endif(enable_lib_static)