tools/cmake/GCCFlags.cmake

   1 ##
   2 ## This file is in charge of setting our paranoid flags with regard to warnings and optimization.
   3 ##
   4 ##   It is only used for gcc and clang. MSVC builds don't load this file.
   5 ##
   6 ##   These flags do break some classical CMake tests, so you don't
   7 ##   want to do so before the very end of the configuration.
   8 ##
   9 ##   Other compiler flags (C/C++ standard version) are tested and set
  10 ##   by the beginning of the configuration, directly in ~/CMakeList.txt
  11
  12 set(warnCFLAGS "")
  13 set(optCFLAGS "")
  14 set(warnCXXFLAGS "")
  15
  16 if(enable_compile_warnings)
  17   set(warnCFLAGS "-fno-common -Wall -Wunused -Wmissing-declarations -Wpointer-arith -Wchar-subscripts -Wcomment -Wformat -Wwrite-strings -Wno-unused-function -Wno-unused-parameter -Wno-strict-aliasing")
  18   if(CMAKE_COMPILER_IS_GNUCC AND (NOT (CMAKE_C_COMPILER_VERSION VERSION_LESS "5.0")))
  19     set(warnCFLAGS "${warnCFLAGS} -Wformat-signedness")
  20   endif()
  21   if(CMAKE_C_COMPILER_ID MATCHES "Clang|GCC")
  22     set(warnCFLAGS "${warnCFLAGS} -Wno-format-nonliteral")
  23   endif()
  24   if(CMAKE_COMPILER_IS_GNUCC)
  25     set(warnCFLAGS "${warnCFLAGS} -Wclobbered -Wno-error=clobbered  -Wno-unused-local-typedefs -Wno-error=attributes")
  26   endif()
  27   if (CMAKE_CXX_COMPILER_ID MATCHES "Intel")
  28     # ignore remark  #1418: external function definition with no prior declaration
  29     # 3179: deprecated conversion of string literal to char* (should be const char*)
  30     # 191: type qualifier is meaningless on cast type
  31     set(warnCFLAGS "${warnCFLAGS} -wd1418 -wd191 -wd3179")
  32   endif()
  33
  34   set(warnCXXFLAGS "${warnCFLAGS} -Wall -Wextra -Wunused -Wmissing-declarations -Wpointer-arith -Wchar-subscripts -Wcomment -Wformat -Wwrite-strings -Wno-unused-function -Wno-unused-parameter -Wno-strict-aliasing")
  35   if(CMAKE_COMPILER_IS_GNUCXX AND (NOT (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "5.0")))
  36     set(warnCFLAGS "${warnCFLAGS} -Wformat-signedness")
  37   endif()
  38   if(CMAKE_CXX_COMPILER_ID MATCHES "Clang|GCC")
  39     set(warnCXXFLAGS "${warnCXXFLAGS} -Wno-format-nonliteral")
  40   endif()
  41   if(CMAKE_COMPILER_IS_GNUCXX)
  42     set(warnCXXFLAGS "${warnCXXFLAGS} -Wclobbered -Wno-error=clobbered  -Wno-unused-local-typedefs -Wno-error=attributes")
  43   endif()
  44   if (CMAKE_CXX_COMPILER_ID MATCHES "Clang")
  45     # don't care about class that become struct, avoid issue of empty C structs
  46     # size (coming from libunwind.h)
  47     set(warnCXXFLAGS "${warnCXXFLAGS} -Wno-mismatched-tags -Wno-extern-c-compat")
  48   endif()
  49
  50   # the one specific to C but refused by C++
  51   set(warnCFLAGS "${warnCFLAGS} -Wmissing-prototypes")
  52
  53   if(CMAKE_Fortran_COMPILER_ID MATCHES "GCC|PGI")
  54     set(CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} -Wall")
  55   endif()
  56   if(CMAKE_Fortran_COMPILER_ID MATCHES "Intel")
  57     set(CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} -warn all")
  58   endif()
  59   set(CMAKE_JAVA_COMPILE_FLAGS "-Xlint")
  60 endif()
  61
  62 # NDEBUG gives a lot of "initialized but unused variables" errors. Don't die anyway.
  63 if(enable_compile_warnings AND enable_debug)
  64   set(warnCFLAGS "${warnCFLAGS} -Werror")
  65   set(warnCXXFLAGS "${warnCXXFLAGS} -Werror")
  66 endif()
  67
  68 # Activate the warnings on #if FOOBAR when FOOBAR has no value
  69 # It breaks on FreeBSD within Boost headers, so activate this only in Pure Hardcore debug mode.
  70 if(enable_maintainer_mode)
  71   set(warnCFLAGS "${warnCFLAGS} -Wundef")
  72   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wundef")
  73 endif()
  74
  75 # Se the optimisation flags
  76 # NOTE, we should CMAKE_BUILD_TYPE for this
  77 if(enable_compile_optimizations)
  78   set(optCFLAGS "-O3 -funroll-loops -fno-strict-aliasing ")
  79 else()
  80   set(optCFLAGS "-O0 ")
  81 endif()
  82 if(enable_compile_optimizations AND CMAKE_COMPILER_IS_GNUCC
  83     AND (NOT enable_model-checking))
  84   # This is redundant (already in -03):
  85   set(optCFLAGS "${optCFLAGS} -finline-functions ")
  86 endif()
  87 if (CMAKE_C_COMPILER_ID MATCHES "Intel")
  88   # honor parentheses when determining the order of expression evaluation.
  89   set(optCFLAGS "${optCFLAGS} -fprotect-parens ")
  90 endif()
  91
  92 # Do not leak the current directory into the binaries
  93 if(CMAKE_COMPILER_IS_GNUCC)
  94   execute_process(COMMAND realpath --relative-to=${CMAKE_BINARY_DIR} ${CMAKE_SOURCE_DIR}
  95     RESULT_VARIABLE RESULT OUTPUT_VARIABLE RELATIVE_SOURCE_DIR ERROR_QUIET OUTPUT_STRIP_TRAILING_WHITESPACE)
  96   if(RESULT EQUAL 0)
  97     message(STATUS "Relative source directory is \"${RELATIVE_SOURCE_DIR}\".")
  98   else()
  99     message(WARNING "Failed to find relative source directory. Using \".\".")
 100     set(RELATIVE_SOURCE_DIR ".")
 101   endif()
 102   set(optCFLAGS "${optCFLAGS} -fdebug-prefix-map=${CMAKE_SOURCE_DIR}=${RELATIVE_SOURCE_DIR}")
 103 endif()
 104
 105 # Configure LTO
 106 # NOTE, cmake 3.0 has a INTERPROCEDURAL_OPTIMIZATION target
 107 #       property for this (http://www.cmake.org/cmake/help/v3.0/prop_tgt/INTERPROCEDURAL_OPTIMIZATION.html)
 108 if(enable_lto) # User wants LTO. Try if we can do that
 109   set(enable_lto OFF)
 110   if(enable_compile_optimizations
 111       AND CMAKE_COMPILER_IS_GNUCC
 112       AND (NOT enable_model-checking))
 113     # On windows, we need 4.8 or higher to enable lto because of http://gcc.gnu.org/bugzilla/show_bug.cgi?id=50293
 114     #   We are experiencing assertion failures even with 4.8 on MinGW.
 115     #   Push the support forward: will see if 4.9 works when we test it.
 116     #
 117     # On Linux, we got the following with GCC 4.8.4 on Centos and Ubuntu
 118     #    lto1: internal compiler error: in output_die, at dwarf2out.c:8478
 119     #    Please submit a full bug report, with preprocessed source if appropriate.
 120     # So instead, we push the support forward
 121
 122     if ( (CMAKE_C_COMPILER_VERSION VERSION_GREATER "4.8.5")
 123          AND (LINKER_VERSION VERSION_GREATER "2.22"))
 124       set(enable_lto ON)
 125     endif()
 126   endif()
 127   if(enable_lto)
 128     message(STATUS "LTO seems usable.")
 129   else()
 130     if(NOT enable_compile_optimizations)
 131       message(STATUS "LTO disabled: Compile-time optimizations turned off.")
 132     else()
 133       if(enable_model-checking)
 134         message(STATUS "LTO disabled when compiling with model-checking.")
 135       else()
 136         message(STATUS "LTO does not seem usable -- try updating your build chain.")
 137       endif()
 138     endif()
 139   endif()
 140 else()
 141   message(STATUS "LTO disabled on the command line.")
 142 endif()
 143 if(enable_lto) # User wants LTO, and it seems usable. Go for it
 144   set(optCFLAGS "${optCFLAGS} -flto ")
 145   # See https://gcc.gnu.org/wiki/LinkTimeOptimizationFAQ#ar.2C_nm_and_ranlib:
 146   # "Since version 4.9 gcc produces slim object files that only contain
 147   # the intermediate representation. In order to handle archives of
 148   # these objects you have to use the gcc wrappers:
 149   # gcc-ar, gcc-nm and gcc-ranlib."
 150   if(${CMAKE_C_COMPILER_ID} STREQUAL "GNU"
 151       AND CMAKE_C_COMPILER_VERSION VERSION_GREATER "4.8")
 152     set (CMAKE_AR gcc-ar)
 153     set (CMAKE_RANLIB gcc-ranlib)
 154   endif()
 155 endif()
 156
 157 if(enable_model-checking AND enable_compile_optimizations)
 158   # Forget it, do not optimize the code (because it confuses the MC):
 159   set(optCFLAGS "-O0 ")
 160   # But you can still optimize this:
 161   foreach(s
 162       src/kernel/lmm/fair_bottleneck.cpp src/kernel/lmm/lagrange.cpp src/kernel/lmm/maxmin.cpp
 163       src/xbt/mmalloc/mm.c
 164       src/xbt/log.c src/xbt/xbt_log_appender_file.c
 165       src/xbt/xbt_log_layout_format.c src/xbt/xbt_log_layout_simple.c
 166       src/xbt/dict.cpp src/xbt/dict_elm.c src/xbt/dict_cursor.c
 167       src/xbt/dynar.cpp
 168       src/xbt/xbt_str.cpp src/xbt/snprintf.c
 169       src/xbt/xbt_os_time.c src/xbt/xbt_os_thread.c
 170       src/xbt/backtrace_linux.cpp
 171       ${MC_SRC_BASE} ${MC_SRC})
 172       set (mcCFLAGS "-O3  -funroll-loops -fno-strict-aliasing")
 173        if(CMAKE_COMPILER_IS_GNUCC)
 174          set (mcCFLAGS "${mcCFLAGS} -finline-functions")
 175       endif()
 176       set_source_files_properties(${s} PROPERTIES COMPILE_FLAGS ${mcCFLAGS})
 177   endforeach()
 178 endif()
 179
 180 if(NOT enable_debug)
 181   set(CMAKE_C_FLAGS "-DNDEBUG ${CMAKE_C_FLAGS}")
 182   set(CMAKE_CXX_FLAGS "-DNDEBUG ${CMAKE_CXX_FLAGS}")
 183 endif()
 184
 185 set(CMAKE_C_FLAGS   "${warnCFLAGS} ${CMAKE_C_FLAGS}   ${optCFLAGS}")
 186 set(CMAKE_CXX_FLAGS "${warnCXXFLAGS} ${CMAKE_CXX_FLAGS} ${optCFLAGS}")
 187
 188 # Try to make Mac a bit more complient to open source standards
 189 if(CMAKE_SYSTEM_NAME MATCHES "Darwin")
 190   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_XOPEN_SOURCE=700 -D_DARWIN_C_SOURCE")
 191 endif()
 192
 193 # Avoid a failure seen with gcc 7.2.0 and ns3 3.27
 194 if(enable_ns3)
 195   set_source_files_properties(src/surf/network_ns3.cpp PROPERTIES COMPILE_FLAGS " -Wno-unused-local-typedef")
 196 endif()
 197
 198 set(TESH_OPTION "")
 199 if(enable_coverage)
 200   find_program(GCOV_PATH gcov)
 201   if(GCOV_PATH)
 202     set(COVERAGE_COMMAND "${GCOV_PATH}" CACHE TYPE FILEPATH FORCE)
 203     set(COVERAGE_EXTRA_FLAGS "-l -p")
 204     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -DCOVERAGE")
 205     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fprofile-arcs -ftest-coverage")
 206     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -fprofile-arcs -ftest-coverage")
 207     set(CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} -fprofile-arcs -ftest-coverage")
 208     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fprofile-arcs -ftest-coverage")
 209     add_definitions(-fprofile-arcs -ftest-coverage)
 210   endif()
 211 endif()
 212
 213 if(enable_address_sanitizer)
 214     set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS} -fsanitize=address -fno-omit-frame-pointer")
 215     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fsanitize=address -fno-omit-frame-pointer")
 216     set(CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} -fsanitize=address")
 217     set(TESH_OPTION --enable-sanitizers)
 218     try_compile(HAVE_SANITIZE_ADDRESS ${CMAKE_BINARY_DIR} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_asan.cpp)
 219     try_compile(HAVE_SANITIZE_ADDRESS_FIBER_SUPPORT ${CMAKE_BINARY_DIR} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_asan.cpp
 220       COMPILE_DEFINITIONS -DCHECK_FIBER_SUPPORT)
 221 else()
 222     set(HAVE_SANITIZE_ADDRESS FALSE CACHE INTERNAL "")
 223     set(HAVE_SANITIZE_ADDRESS_FIBER_SUPPORT FALSE CACHE INTERNAL "")
 224 endif()
 225
 226 if(enable_thread_sanitizer)
 227     set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS} -fsanitize=thread -fno-omit-frame-pointer -no-pie")
 228     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fsanitize=thread -fno-omit-frame-pointer -no-pie")
 229     set(CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} -fsanitize=thread -no-pie")
 230 endif()
 231
 232 if(enable_undefined_sanitizer)
 233     set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS} -fsanitize=undefined -fno-omit-frame-pointer")
 234     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fsanitize=undefined -fno-omit-frame-pointer")
 235     set(CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} -fsanitize=undefined")
 236 endif()
 237
 238 if(NOT $ENV{CFLAGS} STREQUAL "")
 239   message(STATUS "Add CFLAGS: \"$ENV{CFLAGS}\" to CMAKE_C_FLAGS")
 240   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} $ENV{CFLAGS}")
 241 endif()
 242
 243 if(NOT $ENV{CXXFLAGS} STREQUAL "")
 244   message(STATUS "Add CXXFLAGS: \"$ENV{CXXFLAGS}\" to CMAKE_CXX_FLAGS")
 245   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} $ENV{CXXFLAGS}")
 246 endif()
 247
 248 if(NOT $ENV{LDFLAGS} STREQUAL "")
 249   message(STATUS "Add LDFLAGS: \"$ENV{LDFLAGS}\" to CMAKE_C_LINK_FLAGS")
 250   set(CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} $ENV{LDFLAGS}")
 251 endif()
 252
 253 if(MINGW)
 254   # http://stackoverflow.com/questions/10452262/create-64-bit-jni-under-windows
 255   # We don't want to ship libgcc_s_seh-1.dll nor libstdc++-6.dll
 256   set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS}   -static-libgcc")
 257   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -static-libgcc -static-libstdc++")
 258   set(CMAKE_SHARED_LIBRARY_LINK_C_FLAGS   "${CMAKE_SHARED_LIBRARY_LINK_C_FLAGS} -static-libgcc")
 259   set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "${CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS} -static-libgcc -static-libstdc++")
 260
 261   # JNI searches for stdcalls
 262   set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS}   -Wl,--add-stdcall-alias")
 263   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wl,--add-stdcall-alias")
 264   set(CMAKE_SHARED_LIBRARY_LINK_C_FLAGS "${CMAKE_SHARED_LIBRARY_LINK_C_FLAGS} -Wl,--add-stdcall-alias")
 265   set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "${CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS} -Wl,--add-stdcall-alias")
 266
 267   # Specify the data model that we are using (yeah it may help Java)
 268   if(CMAKE_SIZEOF_VOID_P EQUAL 4) # 32 bits
 269     set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS}   -m32")
 270     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -m32")
 271   else()
 272     set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS}   -m64")
 273     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -m64")
 274   endif()
 275 endif()